MCS51系列單片機軟體復位的方法只要用指令使程式從起始地址開始執行,就可以復位單片機,擺脫干擾。通過一個簡單的實驗,揭示了軟體復位的可靠方法。
基本介紹
- 中文名：MCS51系列單片機軟體復位的方法
- 關鍵字：單片機
- 類型：科技論文
- 套用：計算機軟體
產品介紹,運行程式,
產品介紹
摘要：文章指出了一種廣泛流傳的誤解：在MCS-51系列中,只要用指令使程式從起始地址開始執行,就可以復位單片機,擺脫干擾。通過一個簡單的實驗,揭示了軟體復位的可靠方法。
有的單片機（如8098）有專門的復位指令,某些增強型MCS-51系統單片機雖然沒有復位指令,但片內集成了WATCHDOG電路,故抗干擾也不成問題。而普及型MCS-51系列單片機（如8031和8032）既然無復位指令,又不帶硬體WATCHDOS,如果沒有外接硬體WATCHDOG電路,就必須採用軟體抗干擾技術。常用的軟體抗干擾技術有：軟體陷阱、指令冗餘、軟體WATCHDOG等,它們的作用是在系統受干擾時能及時發現,再用軟體的方法使系統復位。所謂軟體復位就是用一系列指令來模仿復位操作,這就是MCS-51系列單片機所特有的軟體復位技術。
運行程式
現用一簡單的實驗說明,實驗電路如附圖所示。接於仿真插座P1.0的發光二極體LED0用來表示主程式的工作情況,接於P1。1的發光二極體LED1用於表示低級中斷子程式的工作情況,接於P1。2的發光二極體LED2用來表示高級中斷子程式的工作情況,接於P3。2口的按鈕用來設立干擾標誌,程式檢測到干擾標誌後故意進入死循環或掉進陷井,模仿受干擾的情況,從而檢驗各種復位方法的實際效果。寮驗初始化程式如下：
ORG 0000H
STAT: LJMP MAIN ;復位入口地址
LJMP PX0 ;按鈕中斷向量（低級中斷）
ORG 000BH
LJMP PT0 ;t0中斷向量（低級中斷）
ORG 001BH
LJMP PT1 ;T1中斷向量（高級中斷）
ORG 0030H
MAIN：
CLR EA
MOV SP,#7
MOV P1,#0FFH
MOV P3,#0FFH
MOV TMOD,#11H
CLR 00H ;干擾標誌初始化
SETB ET0
SETB ET1
SETB EX0
SETB PT1
SETB TR0
SETB TR1
SETB EA
LOOP: CPL P1.0 ;主程式發光二極體LED閃爍
MOV R6,#80H
MOV R7,#0
TT1:
DJNZ R7,TT1
DJNZ R6,TT1
SJMP LOOP
PX0:
SETB 00H ;設立干擾標誌,模擬發生干擾
PT0: CPL P1.1 ;低級中斷程式發光二極體LED1閃爍
RETI
PT1: CPL P1.2 ;高級中斷程式發光二極體LED2閃爍
RETI
END
STAT: LJMP MAIN ;復位入口地址
LJMP PX0 ;按鈕中斷向量（低級中斷）
ORG 000BH
LJMP PT0 ;t0中斷向量（低級中斷）
ORG 001BH
LJMP PT1 ;T1中斷向量（高級中斷）
ORG 0030H
MAIN：
CLR EA
MOV SP,#7
MOV P1,#0FFH
MOV P3,#0FFH
MOV TMOD,#11H
CLR 00H ;干擾標誌初始化
SETB ET0
SETB ET1
SETB EX0
SETB PT1
SETB TR0
SETB TR1
SETB EA
LOOP: CPL P1.0 ;主程式發光二極體LED閃爍
MOV R6,#80H
MOV R7,#0
TT1:
DJNZ R7,TT1
DJNZ R6,TT1
SJMP LOOP
PX0:
SETB 00H ;設立干擾標誌,模擬發生干擾
PT0: CPL P1.1 ;低級中斷程式發光二極體LED1閃爍
RETI
PT1: CPL P1.2 ;高級中斷程式發光二極體LED2閃爍
RETI
END
實驗步驟如下：
1． 按上述程式啟動執行,三個發光二極體都應閃爍（否則應先排除故障）,表示主程式和各中斷子程式正常。因模擬干擾標誌未加檢測,故不受按鈕影響。
2． 修改主程式如下,按下按鈕後主程式即掉入死循環中。
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
JNB 00H,LOOP ;受干擾否？
STOP： LJMP STOP ;掉入死循環。
這時可以看到,主程式停止工作（LED0停止閃爍）,而兩個中斷子程式繼續運行（LED1和LED2繼續閃爍）。
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
JNB 00H,LOOP ;受干擾否？
STOP： LJMP STOP ;掉入死循環。
這時可以看到,主程式停止工作（LED0停止閃爍）,而兩個中斷子程式繼續運行（LED1和LED2繼續閃爍）。
3． 將定時器T1妝作軟體WATCHDOG,將30H單元用作軟體WATCHDOG計數器。主程式中加入一條復位軟體WATCHDOG的指令。
LOOP: CPL P1.0
MOV 30H,#0 ;復位軟體WATCHDOG計數器
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
JNB 00H,LOOP ;受干擾否？
STOP： LJMP STOP ;掉入死循環。
T1中斷子程式修改如下：
PT1: CPL P1.2 ;高級中斷程式發光二極體閃爍
INC 30H
MOV A,30H
ADD A,#0FDH
JC ERR ;達到3次否？
RETI
ERR: LJMP STAT ;軟體WATCHDOG動作
當按下按鈕前,程式正常運行（三個LED全閃）。按下按鈕後,主程式能迅速恢復工作,但兩個中斷子程式被封鎖,不再工作。過程如下：主程式檢測到干擾後進入死循環,不能執行復位30H單元的操作,T1中斷使30H不斷增值,計數到3時,軟體WATCHDOG執行動作,執行一條LJMP指令,使程式從頭執行。MAIN過程中清除了干擾標誌（表示干擾已經過去）,使主程式迅速恢復工作。按理說MAIN過程中也重新設定了各箇中斷,並開放了它們,為什麼中斷不能恢復工作呢？這是因為中斷激活標誌的復位工作被遺忘了,因為它沒有明確的位地址可供編程,直接轉向0000H地址並不能完成真正的復位。軟體復位是使用軟體陷井和軟體WATCHDOG後必須進行的工作,這時程式出錯完全有可能發生中斷子程式中,中斷激活標誌已置位,它將阻止同級中斷回響。由於軟體WATCHDOG是高級中斷,它將阻止所有中斷回響。由此可見,清除中斷激活標誌的得要性,很多文獻的作者回為沒有認識到這一點進入誤區。
LOOP: CPL P1.0
MOV 30H,#0 ;復位軟體WATCHDOG計數器
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
JNB 00H,LOOP ;受干擾否？
STOP： LJMP STOP ;掉入死循環。
T1中斷子程式修改如下：
PT1: CPL P1.2 ;高級中斷程式發光二極體閃爍
INC 30H
MOV A,30H
ADD A,#0FDH
JC ERR ;達到3次否？
RETI
ERR: LJMP STAT ;軟體WATCHDOG動作
當按下按鈕前,程式正常運行（三個LED全閃）。按下按鈕後,主程式能迅速恢復工作,但兩個中斷子程式被封鎖,不再工作。過程如下：主程式檢測到干擾後進入死循環,不能執行復位30H單元的操作,T1中斷使30H不斷增值,計數到3時,軟體WATCHDOG執行動作,執行一條LJMP指令,使程式從頭執行。MAIN過程中清除了干擾標誌（表示干擾已經過去）,使主程式迅速恢復工作。按理說MAIN過程中也重新設定了各箇中斷,並開放了它們,為什麼中斷不能恢復工作呢？這是因為中斷激活標誌的復位工作被遺忘了,因為它沒有明確的位地址可供編程,直接轉向0000H地址並不能完成真正的復位。軟體復位是使用軟體陷井和軟體WATCHDOG後必須進行的工作,這時程式出錯完全有可能發生中斷子程式中,中斷激活標誌已置位,它將阻止同級中斷回響。由於軟體WATCHDOG是高級中斷,它將阻止所有中斷回響。由此可見,清除中斷激活標誌的得要性,很多文獻的作者回為沒有認識到這一點進入誤區。
4． 在所有指令中,只有RETI指令能清除中斷激活標誌。出錯處理程式ERR主要是完成這一功能,其它的善後工作交由復位後的系統去完成。為此,我們重新設計T1中斷子程式如下所示：
PT1: CPL P1.2 ;高級中斷程式發光二極體閃爍
INC 30H ;軟體WATCHDOG計數器增值
MOV A,30H
ADD A,#0FD
JC ERR ;達到3次否？
RETI
ERR: CLR EA ;關中斷
CLR A ;準備復位地址（0000H）
PUSH ACC
PUSH ACC
RETI ;清除中斷激活標誌並復位
這段程式先關中斷,以便後續處理能順利進行,然後用RETI指令替代LJMP指令,從而既清除了中斷激活標誌又完成了轉向0000H的任務。按這樣改好後程式再運行,結果仍不理想：按下按鈕後,有時只有主程式和高級中斷子程式能迅速恢復正常,而低級中斷仍有被關閉的可能。如果按如下方法把干擾轉移到低級中斷中,則按下按鈕後低級中斷必然被關閉：
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
SJMP LOOP
PT0: CPL P1.1
JB 00H,STOP
RETI
STOP： LJMP STOP ;掉入死循環。
仔細分析後可能得出結論：當軟體WATCHDOG是嵌套在低級中斷中起作用時,復位後只清除了高級中斷激活標誌,低級中斷標誌仍然被置位,從而使低級中斷一直被關閉。
PT1: CPL P1.2 ;高級中斷程式發光二極體閃爍
INC 30H ;軟體WATCHDOG計數器增值
MOV A,30H
ADD A,#0FD
JC ERR ;達到3次否？
RETI
ERR: CLR EA ;關中斷
CLR A ;準備復位地址（0000H）
PUSH ACC
PUSH ACC
RETI ;清除中斷激活標誌並復位
這段程式先關中斷,以便後續處理能順利進行,然後用RETI指令替代LJMP指令,從而既清除了中斷激活標誌又完成了轉向0000H的任務。按這樣改好後程式再運行,結果仍不理想：按下按鈕後,有時只有主程式和高級中斷子程式能迅速恢復正常,而低級中斷仍有被關閉的可能。如果按如下方法把干擾轉移到低級中斷中,則按下按鈕後低級中斷必然被關閉：
LOOP: CPL P1.0
MOV R6,#80H
MOV R7,#0H
TT1: DJNZ R7,TT1
DJNZ R6,TT1
SJMP LOOP
PT0: CPL P1.1
JB 00H,STOP
RETI
STOP： LJMP STOP ;掉入死循環。
仔細分析後可能得出結論：當軟體WATCHDOG是嵌套在低級中斷中起作用時,復位後只清除了高級中斷激活標誌,低級中斷標誌仍然被置位,從而使低級中斷一直被關閉。
5． 修改出錯處理如下：
ERR: CLR EA ;正確的軟體復位入口
MOV 66H,#0AAH ;重建上電標誌
MOV 67H,#55H
MOV DPTR,#ERR1 ;準備第一次返回地址
PUSH DPL
PUSH DPH
RETI ;清除高級中斷激活標誌
ERR1: CLR A
PUSH ACC
PUSH ACC
RETI ;清除低級中斷激活標誌
這時,必須執行兩次RETI,才能到達0000H,以保證清除全部中斷激活標誌,達到和硬體復位相同的效果。同樣,軟體陷井也必須由下列三條指令
NOP
NOP
LJMP STAT
改成：
NOP
NOP
LJMP ERR
才能達到目的。
當主程式受到干擾被軟體陷阱捕獲時,中斷標誌並未置位,執行ERR過程中,RETI指令等效於RET指令,同樣可以達到軟體復位的目的。有興趣的讀者可以將軟體陷阱代替死循環,分別用LJMP STAT和LJMP ERR1來替代LJMP ERR,再將干擾檢測分別設在低級中斷和主程式中,實驗結果必然證明同：只有LJMP ERR才能萬無一失地實現軟體復位,使系統擺脫干擾同,恢復正常。在MCS-51單片機的軟體復位過程中,必須連續執行兩次中斷返回指令RETI才能確保系統恢復正常。
ERR: CLR EA ;正確的軟體復位入口
MOV 66H,#0AAH ;重建上電標誌
MOV 67H,#55H
MOV DPTR,#ERR1 ;準備第一次返回地址
PUSH DPL
PUSH DPH
RETI ;清除高級中斷激活標誌
ERR1: CLR A
PUSH ACC
PUSH ACC
RETI ;清除低級中斷激活標誌
這時,必須執行兩次RETI,才能到達0000H,以保證清除全部中斷激活標誌,達到和硬體復位相同的效果。同樣,軟體陷井也必須由下列三條指令
NOP
NOP
LJMP STAT
改成：
NOP
NOP
LJMP ERR
才能達到目的。
當主程式受到干擾被軟體陷阱捕獲時,中斷標誌並未置位,執行ERR過程中,RETI指令等效於RET指令,同樣可以達到軟體復位的目的。有興趣的讀者可以將軟體陷阱代替死循環,分別用LJMP STAT和LJMP ERR1來替代LJMP ERR,再將干擾檢測分別設在低級中斷和主程式中,實驗結果必然證明同：只有LJMP ERR才能萬無一失地實現軟體復位,使系統擺脫干擾同,恢復正常。在MCS-51單片機的軟體復位過程中,必須連續執行兩次中斷返回指令RETI才能確保系統恢復正常。
