Doevents

DoEvents表示函式 返回，轉讓控制權，以便讓作業系統處理其它的事件。儘管 Timer 事件是後台處理的最好工具，對耗時極多的任務，情況更是如此，但是，DoEvents 函式還是提供了一種取消任務的簡便方法。例如，下列代碼將顯示一個 "Process" 按鈕，單擊這個按鈕時，它將變成 "Cancel" 按鈕。再次單擊按鈕又將中斷正在執行的任務。

基本介紹

• 外文名：Doevents
• 語法：DoEvents( )
• 意義：表示函式 返回，轉讓控制權
• 功能：取消任務

套用

語法

DoEvents( )

說明

DoEvents 函式會返回一個 Integer，以代表 Visual Basic 獨立版本中打開的窗體數目，例如，Visual Basic 專業版，在其它的應用程式中，DoEvents 返回 0。

DoEvents 會將控制權傳給作業系統。當作業系統處理完佇列中的事件，並且在 SendKeys 佇列中的所有鍵也都已送出之後，返回控制權。

DoEvents 對於簡化諸如允許用戶取消一個已啟動的過程 — 例如搜尋一個檔案 — 特別有用。對於長時間過程，放棄控制權最好使用定時器或通過委派任務給 ActiveX EXE 部件來完成。以後，任務還是完全獨立於應用程式，多任務及時間片由作業系統來處理。

注意 確保以 DoEvents 放棄控制權的過程，在第一次 DoEvents 返回之前，不能再次被其他部分的代碼調用；否則會產生不可預料的結果。此外，如果其它的應用程式可能會和本過程以不可預知的方式進行互動操作，那么也不要使用 DoEvents，因為此時不能放棄控制權。

使用方法

'此按鈕標題是 "Process"

Private Sub Command1_Click()

'過程的所有實例都共享靜態變數。

Static blnProcessing As Boolean

Dim lngCt As Long

Dim intYieldCt As Integer

Dim dblDummy As Double

'按下按鈕時，檢測是否在處理

If blnProcessing Then

'如果正在處理，則取消

blnProcessing = False

Else

Command1.Caption = "Cancel"

blnProcessing = True

lngCt = 0

'執行一百萬次浮點乘法計算。每一千次後，檢測是否要取消。

Do While blnProcessing And (lngCt < 1000000)

For intYieldCt = 1 To 1000

lngCt = lngCt + 1

dblDummy = lngCt * 3.14159

Next intYieldCt

'DoEvents 語句允許其它事件發生，包括第二次按此按鈕。

DoEvents

Loop

blnProcessing = False

Command1.Caption = "Process"

MsgBox lngCt & " multiplications were performed"

End If

End Sub

DoEvents 將控制切換到操作環境核心。只要此環境中的所有應用程式都有機會回響待處理事件，應用程式就又恢復控制。這不會使應用程式放棄焦點，但會使後台事件能夠得到處理。

這種妥協的結果可能並不總是達到預期目標。例如，下述 Click 事件代碼在單擊按鈕後要一直等候十秒鐘，而後才顯示一條信息。如果在按鈕正在等待期間單擊它，則將以相反順序完成單擊操作。

Private Sub Command2_Click()

Static intClick As Integer

Dim intClickNumber As Integer

Dim dblEndTime As Double

'每次單擊按鈕時賦予唯一數值。

intClick = intClick + 1

intClickNumber = intClick

'等待十秒。

dblEndTime = Timer + 10#

Do While dblEndTime > Timer

'不做任何事情，僅僅允許其它應用程式處理它們的事件。

DoEvents

Loop

MsgBox "Click " & intClickNumber & " is finished"

End Sub

對於通過 DoEvents 放棄控制的事件過程，有時可能希望防止在 DoEvents 返回之前重新調用這一過程。否則將無窮無盡地調用該過程，直到系統資源消耗殆盡。可暫時禁止控制項，或象上例一樣，使用一個靜態的“標誌”變數防止此事發生。

在使用全局數據時避免 DoEvents

當一個函式已通過 DoEvents 放棄控制時，可相當安全地再次調用函式。例如，下一過程將檢測質數並用 DoEvents 語句周期地啟動其它應用程式處理事件：

Function PrimeStatus (TestVal As Long) As Integer

Dim Lim As Integer

PrimeStatus = True

Lim = Sqr(TestVal)

For I = 2 To Lim

If TestVal Mod I = 0 Then

PrimeStatus = False

Exit For

End If

If I Mod 200 = 0 Then DoEvents

Next I

End Function

該代碼中每重複 200 次就調用一次 DoEvents 語句。這樣一來，當該環境的其餘部分對事件作出回響時，只要有必要，PrimeStatus 過程就可繼續計算。

考慮在調用 DoEvents 期間發生的事情。在其它窗體和應用程式處理事件時將暫停執行應用程式代碼。這些事件之一有可能是一個按鈕單擊操作，它將再次啟動 PrimeStatus 過程。

這將導致重新進入 PrimeStatus 過程的，但是，因為在函式每次出現時，堆疊都為其參數和局部變數分配了空間，所以重入不會引發衝突。當然，如果過多調用 PrimeStatus，則可能出現“溢出堆疊空間”錯誤。

如果 PrimeStatus 使用或改變模組級變數或全局數據，情況就會完全不同。此時，在 DoEvents 能夠返回之前執行 PrimeStatus 的另一個實例，這將導致模組數據或全局數據的值完全不同於它們在調用 DoEvents 之前的值。於是，PrimeStatus 的結果將會難以預料。

基本用法

1.窗體啟動時如果要處理的事務太多或者用sleep函式暫停，造成其很久都不能出現時怎么辦?

例如代碼：

Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)'此句寫入模組

Private Sub Form_Load()

Show

'**DoEvents句3

Sleep 5000

End Sub

通常容易想到在sleep前加個show，但還是不能達到預想的效果，窗體雖然出來了，但好象只達到了一半，如果加上第3句，將看到效果大不相同。

2.如果有個很耗時的循環導致程式不回響，怎么辦?

例如：

Dim L As Long

For L = 1 To 1000000

'** DoEvents

Next L

如果無'**，在循環過程中程式無法處理事件，對於用戶來說是不回響，無法控制的

3.想在循環中看到處理過程?

同樣：

Dim L As Long

For L = 1 To 10000

'** DoEvents

Text1.Text=Cstr(l)

Next L

無'** 時將無法看到text1中的變化，而只在循環結束時看到最後結果

4.怎樣中止循環?

如果有：

Private Sub Command1_Click()

Dim L As Long

Do

L = L + 1

Debug.Print L'在立即視窗中顯示

DoEvents

Loop

End Sub

會發現當關閉視窗後，debug中的數據仍然在變化，說明並沒結束

需要如下：

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

IsExit = False

Do While DoEvents

If IsExit = True Then Exit Do

L = L + 1

Loop

End Sub

Private Sub Command2_Click()''或者在form_unload模組中等等

IsExit = True

End Sub

其中 isexit是全局變數

<>；有些人喜歡用end語句來結束程式，小程式固然可以，但當太大，或者調用了某些特殊的api函式後可能導致預想不到的錯誤，如果裝載了許多東西在程式結束時不處理將卸載很慢，而且這種做法也極不符合正規軟體的要求...總之end語句毛病很多，此不詳談，建議少使用甚至不使用

用法難點

1.為什麼還是不能結束?

代碼如下：

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

IsExit = False

Do

If IsExit = True Then Exit Do '句0

DoEvents '** 句1

Text1.Text = CStr(L) '** 句2

L = L + 1

Loop

End Sub

Private Sub Form_Load()

Static N As Long

N = N + 1

MsgBox N

End SubPrivate Sub Form_Unload(Cancel As Integer)

IsExit = True

End Sub

運行結果：啟動時msg顯示1，點擊command1,text1在變化，此時再點form右上角的小差（關閉窗體），發現vb運行控制上的按扭並沒變化，說明程式還在運行.如果編譯成程式後運行，按下ctrl+del+alt也可發現它還沒結束.

通過讀代碼，並沒發現錯誤，怎么回事?

關鍵在於"句2"訪問了控制項的屬性 ：

代碼運行路徑：當在doevents 時，程式釋放控制權，可以接收事件訊息，form-unload事件只能從此處產生，假設此時關閉form,unload事件發生，即doevents後就運行unload代碼，得到isexit=t，並且form卸載，代碼返回到doevents 之後，運行句2.注意現在form 已經卸載了，text1從哪裡來呢? 於是form重新裝載，代碼跳到form_load模組運行，所以在關閉窗體後可以看到msg 顯示2，此模組運行完後再繼續句2後面的代碼，當下次循環遇到 句0時退出循環

另：既然退出了循環，怎么還不能結束?

vb程式規定（其實其他的windows語言一樣）：窗體卸載時並不是立即卸載其模組代碼，而只先卸載窗體中的控制項和一些屬性值，程式中最後一個窗體卸載時才完全卸載.

在這個單窗體程式中，form卸載時因為循環的控制無法卸載代碼，失去了卸載代碼的機會，導致再也不能卸載（因為沒卸載代碼，所以運行的句2是並不會出錯）。

另：既然再次運行了form_load代碼，怎么看不見窗體?

因為程式啟動時窗體的到顯示的訊息，而只運行此模組並沒有（如果在msgbox n語句前加上show，就可以看到它了）

如何解決?

通過以上分析，應該很簡單，把句1 和句2調換一下就可以了，關鍵：

<；仔細分析代碼是如何運行的，避免在form已經卸載了情況下訪問控制項>

2.用了doevents速度太慢了怎么辦?

doevents的代價是速度變慢，但要程式回響又不得不用，其實doevents語句允許任何應用程式執行相關事件，而不僅僅是你自己的程式，所以變得很慢.

可以讓它回響本程式事件動作，需要用到api函式GetInputState，它的聲明語句為：

Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Public Declare Function GetInputState Lib "user32" () As Long

例如用： If GetInputState() Then DoEvents '來代替doevents可使循環運行更快

3.既要同時回響事件又要控制項不變化，怎么辦?

例如在一個長的循環中向listview控制項中添加記錄，無doevents時程式無回響，但有它時控制項又閃的厲害

解決辦法：

a.不一定每次循環都doevents，可以在適當時間時才用,至少沒那么閃

b.套用api函式 ValidateRect 功能是使指定的矩型區域生效，通知Windows不對指定的區域進行重畫 另：InvalidateRect 功能相反，同時需要用到函式 GetClientRect 取得指定對象的矩形區域 套用*rect函式指定listview的矩形區不重畫，即可避免閃爍（但還是要注意恢復重畫，否則看不見了真實效果）

4.控時循環和變速齒輪

請看下面的代碼：

Option Explicit

Private Declare FunctiontimeGetTimeLib "winmm.dll" () As Long

Dim IsExit As Boolean

Private Sub Command1_Click()

Dim L As Long

Dim Kt As Long

IsExit = False

Do

Kt =timeGetTime()

'do something

L = L + 1

Text1.Text = L

'DoEvents '句 1

WhiletimeGetTime- Kt < 50 '句 2

'While Abs(timeGetTime- Kt) < 50 '句 3

'While Abs(timeGetTime- Kt) And (Not IsExit) < 50 '句 4

DoEvents '句 5

Wend

'DoEvents '句 6

If IsExit Then Exit Do

Loop

End Sub

Private Sub Form_Unload(Cancel As Integer)

IsExit = True

End Sub

其中可用的代碼（除去加"'" 號的代碼）就是通常的控時循環代碼

運行代碼並不會出現錯誤，但在循環過程，請開啟變速齒輪看看

當關閉齒輪時，將發現text1.text停止了，別慌，等一段時間它又會繼續（這要看你設定的時間，這裡是50毫秒，如果設定的太長text1.text將半天都沒變化，這是怎么回事?

變速齒輪在啟動時將hook.dll映射到你的程式地址運行，更改了timegettime（）函式獲取的時間

如果在句2和句3間插入debug.print timegettime,timegettime-kt 將發現，在關閉齒輪的瞬間後者變成了負值，timegettime變小了，所以才造成需要等很久

如果是編寫遊戲，而用戶開了齒輪，那可就慘了

解決方案：

a.用句3代替句2，這個方法最簡便，雖然不符實，但不會出問題，建議使用

b.不要句5，換用句6（這樣就能達到效果嗎?) 因為齒輪還是從doevents語句運行時才能插的進來，所以只要kt=timegettime 和 timegettime之間沒有doevents就不會出錯

ab.兩種方法都有些小問題，但無大礙，有興趣者請自己分析

5.程式怎么"死了"?

這只是一些人編寫時沒注意到的小問題，提醒一下：

同樣用上面的代碼，如果設定的時間太短，以至在代碼運行到句2時已經逾時了，句5將不能運行了，當然程式就死了喔，以防萬一，加上句1，所以此時也只能用a方案來解決齒輪的問題了

有必要用句4代替句3 嗎? 除非你設定的時間太長，人家想關閉你的程式要等上好半天。

在MSND上的內容：在使用全局數據時避免 DoEvents

當一個函式已通過 DoEvents 放棄控制時，可相當安全地再次調用函式。例如，下一過程將檢測質數並用 DoEvents 語句周期地啟動其它應用程式處理事件：

Function PrimeStatus (TestVal As Long) As Integer

Dim Lim As Integer

PrimeStatus = True

Lim = Sqr(TestVal)

For I = 2 To Lim

If TestVal Mod I = 0 Then

PrimeStatus = False

Exit For

End If

If I Mod 200 = 0 Then DoEvents

Next I

End Function

該代碼中每重複 200 次就調用一次 DoEvents 語句。這樣一來，當該環境的其餘部分對事件作出回響時，只要有必要，PrimeStatus 過程就可繼續計算。

考慮在調用 DoEvents 期間發生的事情。在其它窗體和應用程式處理事件時將暫停執行應用程式代碼。這些事件之一有可能是一個按鈕單擊操作，它將再次啟動 PrimeStatus 過程。

這將導致重新進入 PrimeStatus 過程的，但是，因為在函式每次出現時，堆疊都為其參數和局部變數分配了空間，所以重入不會引發衝突。當然，如果過多調用 PrimeStatus，則可能出現“溢出堆疊空間”錯誤。

如果 PrimeStatus 使用或改變模組級變數或全局數據，情況就會完全不同。此時，在 DoEvents 能夠返回之前執行 PrimeStatus 的另一個實例，這將導致模組數據或全局數據的值完全不同於它們在調用 DoEvents 之前的值。於是，PrimeStatus 的結果將會難以預料。